SUMMARY = "A console image with some additional tools"
HOMEPAGE = "https://blackfinn.de"
LICENSE = "MIT"

IMAGE_FEATURES += "package-management"

inherit core-image

CORE_OS = " \
    openssh \
    openssh-keygen \
    openssh-sftp-server \
    psplash \
    tzdata \
"

KERNEL_EXTRA_INSTALL = " \
    kernel-modules \
 "

WIFI_SUPPORT = " \
    iw \
    linux-firmware-rtl8192cu \
    wireless-tools \
    wpa-supplicant \
 "

DEV_SDK_INSTALL = " \
    file \
    git \
    make \
    perl-modules \
    pkgconfig \
    python-modules \
 "

EXTRA_TOOLS_INSTALL = " \
    acpid \
    bc \
    bzip2 \
    ethtool \
    findutils \
    i2c-tools \
    less \
    procps \
    rsync \
    sysfsutils \
    unzip \
    util-linux \
    util-linux-blkid \
    wget \
    curl \
    zip \
 "

IMAGE_INSTALL += " \
    ${CORE_OS} \
    ${DEV_SDK_INSTALL} \
    ${EXTRA_TOOLS_INSTALL} \
    ${KERNEL_EXTRA_INSTALL} \
    ${WIFI_SUPPORT} \
 "

set_local_timezone() {
    ln -sf /usr/share/zoneinfo/Etc/UTC ${IMAGE_ROOTFS}/etc/localtime
}

disable_bootlogd() {
    echo BOOTLOGD_ENABLE=no > ${IMAGE_ROOTFS}/etc/default/bootlogd
}

ROOTFS_POSTPROCESS_COMMAND += " \
    set_local_timezone ; \
    disable_bootlogd ; \
 "

export IMAGE_BASENAME = "console-image"