inherit core-image extrausers

IMAGE_FEATURES += "package-management"

# Encrypt the password with: echo "<password>" | openssl passwd -1 -stdin
EXTRA_USERS_PARAMS = " \
    usermod -p '\$1\$4h5Qdc3i\$Vke4J2Ci5z.D3TtFDmV9r/' root; \
    useradd -p '\$1\$4h5Qdc3i\$Vke4J2Ci5z.D3TtFDmV9r/' tkl; \
"

CORE_OS = " \
    openssh \
    openssh-keygen \
    openssh-sftp-server \
    psplash \
    tzdata \
"

KERNEL_EXTRA_INSTALL = " \
    kernel-modules \
 "

WIFI_SUPPORT = " \
    iw \
    wpa-supplicant \
 "

DEV_SDK_INSTALL = " \
    file \
    perl-modules \
    pkgconfig \
    python3-modules \
 "

EXTRA_TOOLS_INSTALL = " \
    acpid \
    bc \
    bzip2 \
    dosfstools \
    e2fsprogs-mke2fs \
    ethtool \
    findutils \
    i2c-tools \
    less \
    procps \
    rsync \
    sysfsutils \
    unzip \
    util-linux \
    util-linux-blkid \
    vim \
    wget \
    curl \
    zip \
    ntp \
 "

MQTT = " \
"

PYTHON_LIBS = " \
"

IMAGE_INSTALL += " \
    ${CORE_OS} \
    ${DEV_SDK_INSTALL} \
    ${EXTRA_TOOLS_INSTALL} \
    ${KERNEL_EXTRA_INSTALL} \
    ${WIFI_SUPPORT} \
    ${MQTT} \
    ${PYTHON_LIBS} \
"

IMAGE_INSTALL_append_beaglebone-yocto = " linux-firmware-rtl8192cu"

set_local_timezone() {
    ln -sf /usr/share/zoneinfo/Europe/Berlin ${IMAGE_ROOTFS}/etc/localtime
}

disable_bootlogd() {
    echo BOOTLOGD_ENABLE=no > ${IMAGE_ROOTFS}/etc/default/bootlogd
}

ROOTFS_POSTPROCESS_COMMAND += " \
    set_local_timezone ; \
    disable_bootlogd ; \
 "